AKINSOFT WOLVOX Script Geliştirme: eksik olan özelliği programın içinden ekleyin.

Tüm satırları dolaşan denetim

Başlık kaydedilirken bütün hareket satırları kontrol edilir. Hata bulunursa imleç hatalı satırda bırakılır; kullanıcı hangi satır olduğunu doğrudan görür.

// Genel Script
procedure SiparisSatirDenetle;
var
  EskiRecNo: Integer;
  Hatali: Boolean;
begin
  if not SipHr_Ds.Active then Exit;
  if SipHr_Ds.IsEmpty then Exit;   // başlık ilk kez kaydedilirken satır yoktur

  Hatali := False;
  EskiRecNo := SipHr_Ds.RecNo;
  SipHr_Ds.DisableControls;
  try
    SipHr_Ds.First;
    while not SipHr_Ds.Eof do
    begin
      if SipHr_Ds.FieldByName('VADE_GUNU').AsInteger <= 0 then
      begin
        Hatali := True;
        Break;                         // imleç hatalı satırda kalsın
      end;
      SipHr_Ds.Next;
    end;
    if not Hatali then SipHr_Ds.RecNo := EskiRecNo;
  finally
    SipHr_Ds.EnableControls;
  end;

  if Hatali then
  begin
    ShowMessage('Tüm satırlarda Vade Günü sıfırdan büyük olmalıdır!');
    Abort;
  end;
end;

Ana menüye özel başlık

WOLVOX ana menüsüne kendi menünüzü ekler, tıklanınca Tasarım sekmesinde hazırladığınız formu açar.

// Genel Script
var
  YeniMenu, YeniAlt: TMenuItem;

procedure OzelFormAc(Sender: TObject);
begin
  AsFormCreate('OZEL_RAPOR');
end;

procedure MenuEkle;
begin
  YeniMenu := TMenuItem.Create(Self);
  YeniMenu.Caption := 'Özel İşlemler';
  MainMenu1.Items.Add(YeniMenu);

  YeniAlt := AsGenel1.AddMenuItem(YeniMenu, 'Özel Rapor', -1);
  SetEventMethod(YeniAlt, 'OnClick', 'OzelFormAc');
end;

// Event Script → Script → OnStart → İşlem Öncesi
begin
  MenuEkle;

Veritabanından tek değer okumak

Güncel döviz kurunu form açılırken getirir. Script motorunda varsayılan parametre yoktur; beş parametrenin hepsi yazılmalıdır.

var
  SQL: String;
  Kur: Extended;
begin
  SQL := 'SELECT TOP 1 SATIS_FIYATI FROM DOVIZ_HAREKET ' +
         'WHERE DOVIZ_BIRIMI = ''$'' ORDER BY TARIHI DESC';
  Kur := AsGenel1.SQLCalistir1(Uretim_Q.Connection, SQL, 0, False, False);

Satırda zorunlu alan denetimi

Sipariş satırı kaydedilmeden önce iki alan kontrol edilir. Kural sağlanmazsa satır kaydedilmez, kullanıcı neyi düzeltmesi gerektiğini görür.

// Event Script → SipHr_Ds → BeforePost → İşlem Öncesi
begin
  if DataSet.FieldByName('OZEL_KODU').AsString = '' then
  begin
    ShowMessage('Özel Kodu boş bırakılamaz!');
    Abort;
  end;

  if DataSet.FieldByName('VADE_GUNU').AsInteger <= 0 then
  begin
    ShowMessage('Vade Günü sıfırdan büyük olmalıdır!');
    Abort;
  end;

Ekrana yeni etiket ve alan eklemek

Mevcut bir bileşenin hemen altına etiket ve sayı alanı eklenir. Konum sabit koordinatla değil, o bileşene göre hesaplanır; form yeniden açıldığında alan ikinci kez eklenmez.

// Genel Script
var
  KurLabel : TsLabel;
  KurEdit  : TsCalcEdit;

procedure KurAlaniEkle;
begin
  if CheckBLOKE.Parent.FindComponent('KurLabel') <> nil then Exit;

  KurLabel := TsLabel.Create(CheckBLOKE.Parent);
  KurLabel.Name    := 'KurLabel';
  KurLabel.Parent  := CheckBLOKE.Parent;
  KurLabel.Caption := 'USD Kur';
  KurLabel.Left    := CheckBLOKE.Left;
  KurLabel.Top     := CheckBLOKE.Top + CheckBLOKE.Height + 18;

  KurEdit := TsCalcEdit.Create(CheckBLOKE.Parent);
  KurEdit.Name   := 'KurEdit';
  KurEdit.Parent := CheckBLOKE.Parent;
  KurEdit.Left   := KurLabel.Left + KurLabel.Width + 10;
  KurEdit.Top    := KurLabel.Top - 4;
end;

// Event Script → Script → OnStart → İşlem Öncesi
begin
  KurAlaniEkle;